Function: mouse-start-end

mouse-start-end is a byte-compiled function defined in mouse.el.gz.

Signature

(mouse-start-end START END MODE)

Documentation

Return a list of region bounds based on START and END according to MODE.

If MODE is 0 then set point to (min START END), mark to (max START END). If MODE is 1 then set point to start of word at (min START END), mark to end of word at (max START END). If MODE is 2 then do the same for lines.

Source Code

;; Defined in /usr/src/emacs/lisp/mouse.el.gz
(defun mouse-start-end (start end mode)
  "Return a list of region bounds based on START and END according to MODE.
If MODE is 0 then set point to (min START END), mark to (max START END).
If MODE is 1 then set point to start of word at (min START END),
mark to end of word at (max START END).
If MODE is 2 then do the same for lines."
  (if (> start end)
      (let ((temp start))
        (setq start end
              end temp)))
  (setq mode (mod mode 3))
  (cond ((= mode 0)
	 (list start end))
        ((and (= mode 1)
              (= start end)
	      (char-after start)
              (= (syntax-class-to-char
                  (syntax-class (syntax-after start)))
                 ?\())
         (list start
               (save-excursion
                 (goto-char start)
                 (forward-sexp 1)
                 (point))))
        ((and (= mode 1)
              (= start end)
	      (char-after start)
              (= (syntax-class-to-char
                  (syntax-class (syntax-after start)))
                 ?\)))
         (list (save-excursion
                 (goto-char (1+ start))
                 (backward-sexp 1)
                 (point))
               (1+ start)))
	((and (= mode 1)
              (= start end)
	      (char-after start)
              (= (syntax-class-to-char
                  (syntax-class (syntax-after start)))
                 ?\"))
	 (let ((open (or (eq start (point-min))
			 (save-excursion
			   (goto-char (- start 1))
			   (looking-at "\\s(\\|\\s \\|\\s>")))))
	   (if open
	       (list start
		     (save-excursion
		       (condition-case nil
			   (progn
			     (goto-char start)
			     (forward-sexp 1)
			     (point))
			 (error end))))
	     (list (save-excursion
		     (condition-case nil
			 (progn
			   (goto-char (1+ start))
			   (backward-sexp 1)
			   (point))
		       (error end)))
		   (1+ start)))))
        ((= mode 1)
	 (list (save-excursion
		 (goto-char start)
		 (mouse-skip-word -1)
		 (point))
	       (save-excursion
		 (goto-char end)
		 (mouse-skip-word 1)
		 (point))))
        ((= mode 2)
	 (list (save-excursion
		 (goto-char start)
		 (line-beginning-position 1))
	       (save-excursion
		 (goto-char end)
		 (forward-line 1)
		 (point))))))