Function: newsticker--get-news-by-wget

newsticker--get-news-by-wget is a byte-compiled function defined in newst-backend.el.gz.

Signature

(newsticker--get-news-by-wget FEED-NAME URL WGET-ARGUMENTS)

Documentation

Get news for the site FEED-NAME from address URL using wget.

WGET-ARGUMENTS is a list of arguments for wget. See newsticker-get-news.

Source Code

;; Defined in /usr/src/emacs/lisp/net/newst-backend.el.gz
(defun newsticker--get-news-by-wget (feed-name url wget-arguments)
  "Get news for the site FEED-NAME from address URL using wget.
WGET-ARGUMENTS is a list of arguments for wget.
See `newsticker-get-news'."
  (let ((buffername (concat " *newsticker-wget-" feed-name "*")))
    (with-current-buffer (get-buffer-create buffername)
      (erase-buffer)
      ;; throw an error if there is an old wget-process around
      (if (get-process feed-name)
          (error "Another wget-process is running for %s" feed-name))
      ;; start wget
      (let* ((args (append wget-arguments (list url)))
             (proc (apply #'start-process feed-name buffername
                          newsticker-wget-name args)))
        (set-process-coding-system proc 'no-conversion 'no-conversion)
        (set-process-sentinel proc #'newsticker--sentinel)
        (process-put proc 'nt-feed-name feed-name)
        (setq newsticker--process-ids (cons (process-id proc)
                                            newsticker--process-ids))
        (force-mode-line-update)))))