Function: nnbabyl-request-accept-article

nnbabyl-request-accept-article is a byte-compiled function defined in nnbabyl.el.gz.

Signature

(nnbabyl-request-accept-article GROUP &optional SERVER LAST)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnbabyl.el.gz
(deffoo nnbabyl-request-accept-article (group &optional server last)
  (nnbabyl-possibly-change-newsgroup group server)
  (nnmail-check-syntax)
  (let ((buf (current-buffer))
	result) ;; beg
    (and
     (nnmail-activate 'nnbabyl)
     (save-excursion
       (goto-char (point-min))
       (search-forward "\n\n" nil t)
       (forward-line -1)
       (save-excursion
	 (while (re-search-backward "^X-Gnus-Newsgroup: " nil t) ;; beg
	   (delete-region (point) (progn (forward-line 1) (point)))))
       (when nnmail-cache-accepted-message-ids
	 (nnmail-cache-insert (nnmail-fetch-field "message-id")
			      group
			      (nnmail-fetch-field "subject")
			      (nnmail-fetch-field "from")))
       (setq result
	     (if (stringp group)
		 (list (cons group (nnbabyl-active-number group)))
	       (nnmail-article-group 'nnbabyl-active-number)))
       (if (and (null result)
		(yes-or-no-p "Moved to `junk' group; delete article? "))
	   (setq result 'junk)
	 (setq result (car (nnbabyl-save-mail result))))
       (set-buffer nnbabyl-mbox-buffer)
       (goto-char (point-max))
       (search-backward "\n\^_")
       (goto-char (match-end 0))
       (insert-buffer-substring buf)
       (when last
	 (when nnmail-cache-accepted-message-ids
	   (nnmail-cache-insert (nnmail-fetch-field "message-id")
				group
				(nnmail-fetch-field "subject")
				(nnmail-fetch-field "from")))
	 (save-buffer)
	 (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))
       result))))