Function: nnfolder-goto-article

nnfolder-goto-article is a byte-compiled function defined in nnfolder.el.gz.

Signature

(nnfolder-goto-article ARTICLE)

Documentation

Place point at the start of the headers of ARTICLE.

ARTICLE can be an article number or a Message-ID. Returns t if successful, nil otherwise.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnfolder.el.gz
(defun nnfolder-goto-article (article)
  "Place point at the start of the headers of ARTICLE.
ARTICLE can be an article number or a Message-ID.
Returns t if successful, nil otherwise."
  (let ((art-string (nnfolder-article-string article))
	start found)
    ;; It is likely that we are at or before the delimiter line.
    ;; We therefore go to the end of the previous line, and start
    ;; searching from there.
    (beginning-of-line)
    (unless (bobp)
      (forward-char -1))
    (setq start (point))
    ;; First search forward.
    (while (and (setq found (search-forward art-string nil t))
		(not (nnmail-within-headers-p))))
    ;; If unsuccessful, search backward from where we started,
    (unless found
      (goto-char start)
      (while (and (setq found (search-backward art-string nil t))
		  (not (nnmail-within-headers-p)))))
    (when found
      (nnmail-search-unix-mail-delim-backward))))