Function: nnmail-parse-active

nnmail-parse-active is a byte-compiled function defined in nnmail.el.gz.

Signature

(nnmail-parse-active)

Documentation

Parse the active file in the current buffer and return an alist.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmail.el.gz
(defun nnmail-parse-active ()
  "Parse the active file in the current buffer and return an alist."
  (goto-char (point-min))
  (unless (re-search-forward "[\\\"]" nil t)
    (goto-char (point-max))
    (while (re-search-backward "[][';?()#]" nil t)
      (insert ?\\)))
  (goto-char (point-min))
  (let ((buffer (current-buffer))
	group-assoc group max min)
    (while (not (eobp))
      (condition-case nil
	  (progn
            (narrow-to-region (point) (line-end-position))
	    (setq group (read buffer)
		  group
		  (cond ((symbolp group)
			 (symbol-name group))
			((numberp group)
			 (number-to-string group))
                        ((stringp group)
			 group)))
	    (if (and (numberp (setq max (read buffer)))
		     (numberp (setq min (read buffer))))
		(push (list group (cons min max))
		      group-assoc)))
	(error nil))
      (widen)
      (forward-line 1))
    group-assoc))