Function: nnmairix-determine-original-group-from-path

nnmairix-determine-original-group-from-path is a byte-compiled function defined in nnmairix.el.gz.

Signature

(nnmairix-determine-original-group-from-path MID SERVER)

Documentation

Determine original group(s) for message-id MID from the file path.

The file path is obtained through a mairix search for the id on SERVER.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmairix.el.gz
(defun nnmairix-determine-original-group-from-path (mid server)
  "Determine original group(s) for message-id MID from the file path.
The file path is obtained through a mairix search for the id on
SERVER."
  (nnmairix-open-server server)
  (while (string-match "[<>]" mid)
    (setq mid (replace-match "" t t mid)))
  ;; mairix somehow does not like '$' in message-id
  (when (string-search "$" mid)
    (setq mid (concat mid "=")))
  (while (string-match "\\$" mid)
    (setq mid (replace-match "=," t t mid)))
  (let (allgroups)
    (if (zerop (nnmairix-call-mairix-binary-raw
		(split-string nnmairix-mairix-command)
		(list (concat "m:" mid))))
	(with-current-buffer nnmairix-mairix-output-buffer
	  (goto-char (point-min))
	  (while (re-search-forward "^/.*$" nil t)
	    (push (nnmairix-get-group-from-file-path (match-string 0))
		  allgroups)
	    (forward-line 1)))
      (error "Mairix could not find original article.  See buffer %s for details"
	     nnmairix-mairix-output-buffer))
    allgroups))