Function: nnmairix-update-and-clear-marks

nnmairix-update-and-clear-marks is a byte-compiled function defined in nnmairix.el.gz.

Signature

(nnmairix-update-and-clear-marks GROUP &optional METHOD)

Documentation

Update group and clear all marks from GROUP using METHOD.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmairix.el.gz
(defun nnmairix-update-and-clear-marks (group &optional method)
  "Update group and clear all marks from GROUP using METHOD."
  (let ((method (or method
		    (gnus-find-method-for-group group)))
	(corr (gnus-group-get-parameter group 'numcorr t))
	info)
    (unless (or (gnus-group-prefixed-p group)
		(not method))
      (setq group (gnus-group-prefixed-name group method)))
    (if (eq (nth 0 method) 'nnmairix)
	(save-excursion
	  (nnmairix-open-server (nth 1 method))
	  (set-buffer gnus-group-buffer)
	  ;; (gnus-group-set-parameter group 'propmarks nil)
	  (setq info (gnus-get-info group))
	  ;; Clear active and info
	  (gnus-set-active group nil)
	  (gnus-info-clear-data info)
	  ;; Delete and re-create group if needed
	  (nnmairix-delete-recreate-group group)
	  ;; set flag that group has changed for article number correction
	  (when (member nnmairix-backend nnmairix-delete-and-create-on-change)
	    (when corr
	      (setcar corr t)
	      (gnus-group-set-parameter group 'numcorr corr)))
	  (gnus-group-jump-to-group group)
	  (gnus-group-get-new-news-this-group))
      (error "`nnmairix-update-and-clear-marks' called with non-nnmairix group"))))