Function: nnmairix-update-groups

nnmairix-update-groups is an interactive and byte-compiled function defined in nnmairix.el.gz.

Signature

(nnmairix-update-groups SERVERNAME &optional SKIPDEFAULT UPDATEDB)

Documentation

Update all search groups on SERVERNAME.

If SKIPDEFAULT is t, the default search group will not be updated. If UPDATEDB is t, database for SERVERNAME will be updated first.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmairix.el.gz
(defun nnmairix-update-groups (servername &optional skipdefault updatedb)
  "Update all search groups on SERVERNAME.
If SKIPDEFAULT is t, the default search group will not be
updated.
If UPDATEDB is t, database for SERVERNAME will be updated first."
  (interactive (list (gnus-completing-read "Update groups on server"
				(nnmairix-get-nnmairix-servers))))
  (save-excursion
    (when (string-match ".*:\\(.*\\)" servername)
      (setq servername (match-string 1 servername)))
    (if (not (assoc (format "nnmairix:%s" servername)
		    (nnmairix-get-nnmairix-servers)))
	(nnheader-message 3 "Server %s not opened" servername)
      (when updatedb
	(let ((nnmairix-mairix-synchronous-update t))
	  (nnmairix-update-database
	   (list (list (format "nnmairix:%s" servername))))))
      (let ((groups (nnmairix-get-groups-from-server servername))
	    default)
	(when skipdefault
	  (setq default
		(format "nnmairix+%s:%s"
			servername
			(cadr
			 (assoc 'nnmairix-default-group
				(gnus-server-to-method
				 (format "nnmairix:%s" servername)))))))
	(dolist (cur groups)
	  (unless (and skipdefault
		       (string= (car cur) default))
	    (gnus-group-jump-to-group (car cur))
	    (gnus-group-mark-group 1)))
	(gnus-group-get-new-news-this-group)))))