Function: nnmbox-retrieve-headers

nnmbox-retrieve-headers is a byte-compiled function defined in nnmbox.el.gz.

Signature

(nnmbox-retrieve-headers SEQUENCE &optional NEWSGROUP SERVER FETCH-OLD)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmbox.el.gz
(deffoo nnmbox-retrieve-headers (sequence &optional newsgroup server _fetch-old)
  (with-current-buffer nntp-server-buffer
    (erase-buffer)
    (let ((number (length sequence))
	  (count 0)
	  article start stop)
      (nnmbox-possibly-change-newsgroup newsgroup server)
      (while sequence
	(setq article (car sequence))
	(set-buffer nnmbox-mbox-buffer)
	(when (nnmbox-find-article article)
	  (setq start
		(save-excursion
		  (re-search-backward
		   (concat "^" message-unix-mail-delimiter) nil t)
		  (point)))
	  (search-forward "\n\n" nil t)
	  (setq stop (1- (point)))
	  (set-buffer nntp-server-buffer)
	  (insert (format "221 %d Article retrieved.\n" article))
	  (insert-buffer-substring nnmbox-mbox-buffer start stop)
	  (goto-char (point-max))
	  (insert ".\n"))
	(setq sequence (cdr sequence))
	(setq count (1+ count))
	(and (numberp nnmail-large-newsgroup)
	     (> number nnmail-large-newsgroup)
	     (zerop (% count 20))
	     (nnheader-message 5 "nnmbox: Receiving headers... %d%%"
			       (floor (* count 100.0) number))))

      (and (numberp nnmail-large-newsgroup)
	   (> number nnmail-large-newsgroup)
	   (nnheader-message 5 "nnmbox: Receiving headers...done"))

      (set-buffer nntp-server-buffer)
      (nnheader-fold-continuation-lines)
      'headers)))