Function: org-agenda-fontify-priorities

org-agenda-fontify-priorities is an interactive and byte-compiled function defined in org-agenda.el.gz.

Signature

(org-agenda-fontify-priorities)

Documentation

Make highest priority lines bold, and lowest italic.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-agenda.el.gz
(defun org-agenda-fontify-priorities ()
  "Make highest priority lines bold, and lowest italic."
  (interactive)
  (mapc (lambda (o) (when (eq (overlay-get o 'org-type) 'org-priority)
		      (delete-overlay o)))
	(overlays-in (point-min) (point-max)))
  (save-excursion
    (let (b e p ov h l)
      (goto-char (point-min))
      (while (re-search-forward org-priority-regexp nil t)
	(setq h (or (get-char-property (point) 'org-priority-highest)
		    org-priority-highest)
	      l (or (get-char-property (point) 'org-priority-lowest)
		    org-priority-lowest)
	      p (string-to-char (match-string 2))
	      b (match-beginning 1)
	      e (if (eq org-agenda-fontify-priorities 'cookies)
		    (1+ (match-end 2))
                  (line-end-position))
	      ov (make-overlay b e))
	(overlay-put
	 ov 'face
	 (let ((special-face
		(cond ((org-face-from-face-or-color
			'priority 'org-priority
			(cdr (assoc p org-priority-faces))))
		      ((and (listp org-agenda-fontify-priorities)
			    (org-face-from-face-or-color
			     'priority 'org-priority
			     (cdr (assoc p org-agenda-fontify-priorities)))))
		      ((equal p l) 'italic)
		      ((equal p h) 'bold))))
	   (if special-face (list special-face 'org-priority) 'org-priority)))
	(overlay-put ov 'org-type 'org-priority)))))