Function: org-agenda-view-mode-dispatch

org-agenda-view-mode-dispatch is an interactive and byte-compiled function defined in org-agenda.el.gz.

Signature

(org-agenda-view-mode-dispatch)

Documentation

Call one of the view mode commands.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-agenda.el.gz
(defun org-agenda-view-mode-dispatch ()
  "Call one of the view mode commands."
  (interactive)
  (org-unlogged-message
   "View: [d]ay  [w]eek  for[t]night  [m]onth  [y]ear  [SPC]reset  [q]uit/abort
       time[G]rid   [[]inactive  [f]ollow      [l]og    [L]og-all   [c]lockcheck
       [a]rch-trees [A]rch-files clock[R]eport include[D]iary       [E]ntryText")
  (pcase (read-char-exclusive)
    (?\ (call-interactively 'org-agenda-reset-view))
    (?d (call-interactively 'org-agenda-day-view))
    (?w (call-interactively 'org-agenda-week-view))
    (?t (call-interactively 'org-agenda-fortnight-view))
    (?m (call-interactively 'org-agenda-month-view))
    (?y (call-interactively 'org-agenda-year-view))
    (?l (call-interactively 'org-agenda-log-mode))
    (?L (org-agenda-log-mode '(4)))
    (?c (org-agenda-log-mode 'clockcheck))
    ((or ?F ?f) (call-interactively 'org-agenda-follow-mode))
    (?a (call-interactively 'org-agenda-archives-mode))
    (?A (org-agenda-archives-mode 'files))
    ((or ?R ?r) (call-interactively 'org-agenda-clockreport-mode))
    ((or ?E ?e) (call-interactively 'org-agenda-entry-text-mode))
    (?G (call-interactively 'org-agenda-toggle-time-grid))
    (?D (call-interactively 'org-agenda-toggle-diary))
    (?\! (call-interactively 'org-agenda-toggle-deadlines))
    (?\[ (let ((org-agenda-include-inactive-timestamps t))
	   (org-agenda-check-type t 'agenda)
	   (org-agenda-redo))
	 (message "Display now includes inactive timestamps as well"))
    (?q (message "Abort"))
    (key (user-error "Invalid key: %s" key))))