Function: org-babel-disassemble-tables

org-babel-disassemble-tables is a byte-compiled function defined in ob-core.el.gz.

Signature

(org-babel-disassemble-tables VARS HLINES COLNAMES ROWNAMES)

Documentation

Parse tables for further processing.

Process the variables in VARS according to the HLINES, ROWNAMES and COLNAMES header arguments. Return a list consisting of the vars, cnames and rnames.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-core.el.gz
(defun org-babel-disassemble-tables (vars hlines colnames rownames)
  "Parse tables for further processing.
Process the variables in VARS according to the HLINES,
ROWNAMES and COLNAMES header arguments.  Return a list consisting
of the vars, cnames and rnames."
  (let (cnames rnames)
    (list
     (mapcar
      (lambda (var)
        (when (proper-list-p (cdr var))
          (when (and (not (equal colnames "no"))
                     ;; Compatibility note: avoid `length>', which
                     ;; isn't available until Emacs 28.
                     (or colnames
                         ;; :colnames nil (default)
                         ;; Auto-assign column names when the table
                         ;; has hline as the second line after
                         ;; non-hline row.
                         (and (> (length (cdr var)) 1)
                              (not (eq (car (cdr var)) 'hline)) ; first row
                              (eq (nth 1 (cdr var)) 'hline) ; second row
                              (not (member 'hline (cddr (cdr var)))) ; other rows
                              )))
            (let ((both (org-babel-get-colnames (cdr var))))
              (setq cnames (cons (cons (car var) (cdr both))
                                 cnames))
              (setq var (cons (car var) (car both)))))
          (when (and rownames (not (equal rownames "no")))
            (let ((both (org-babel-get-rownames (cdr var))))
              (setq rnames (cons (cons (car var) (cdr both))
                                 rnames))
              (setq var (cons (car var) (car both)))))
          (when (and hlines (not (equal hlines "yes")))
            (setq var (cons (car var) (org-babel-del-hlines (cdr var))))))
        var)
      vars)
     (reverse cnames) (reverse rnames))))