Function: org-cite-biblatex--atomic-arguments

org-cite-biblatex--atomic-arguments is a byte-compiled function defined in oc-biblatex.el.gz.

Signature

(org-cite-biblatex--atomic-arguments REFERENCES INFO &optional NO-OPT)

Documentation

Build argument for the list of citation REFERENCES.

When NO-OPT argument is non-nil, only provide mandatory arguments.

Source Code

;; Defined in /usr/src/emacs/lisp/org/oc-biblatex.el.gz
(defun org-cite-biblatex--atomic-arguments (references info &optional no-opt)
  "Build argument for the list of citation REFERENCES.
When NO-OPT argument is non-nil, only provide mandatory arguments."
  (let ((mandatory
         (format "{%s}"
                 (mapconcat (lambda (r) (org-element-property :key r))
                            references
                            ","))))
    (if no-opt mandatory
      (let* ((origin (pcase references
                       (`(,reference) reference)
                       (`(,reference . ,_)
                        (org-element-parent reference))))
             (suffix (org-element-property :suffix origin))
             (prefix (org-element-property :prefix origin)))
        (concat (and prefix
                     (format "[%s]" (org-trim (org-export-data prefix info))))
                (cond
                 (suffix (format "[%s]"
                                 (org-trim (org-export-data suffix info))))
                 (prefix "[]")
                 (t nil))
                mandatory)))))