Function: org-cite-list-bibliography-files

org-cite-list-bibliography-files is a byte-compiled function defined in oc.el.gz.

Signature

(org-cite-list-bibliography-files)

Documentation

List all bibliography files defined in the buffer.

Source Code

;; Defined in /usr/src/emacs/lisp/org/oc.el.gz
;;; Generic tools
(defun org-cite-list-bibliography-files ()
  "List all bibliography files defined in the buffer."
  (delete-dups
   (append (mapcar (lambda (value)
		     (pcase value
		       (`(,f . ,d)
                        (setq f (org-strip-quotes f))
                        (if (or (file-name-absolute-p f)
                                (file-remote-p f)
                                (equal d default-directory))
                            ;; Keep absolute paths, remote paths, and
                            ;; local relative paths.
                            f
                          ;; Adjust relative bibliography path for
                          ;; #+SETUP files located in other directory.
                          ;; Also, see `org-export--update-included-link'.
                          (file-relative-name
                           (expand-file-name f d) default-directory)))))
		   (pcase (org-collect-keywords
                           '("BIBLIOGRAPHY") nil '("BIBLIOGRAPHY"))
		     (`(("BIBLIOGRAPHY" . ,pairs)) pairs)))
	   org-cite-global-bibliography)))