Function: org-columns--collect-values

org-columns--collect-values is a byte-compiled function defined in org-colview.el.gz.

Signature

(org-columns--collect-values &optional COMPILED-FMT)

Documentation

Collect values for columns on the current line.

Return a list of triplets (SPEC VALUE DISPLAYED) suitable for org-columns--display-here.

This function assumes org-columns-current-fmt-compiled is initialized is set in the current buffer. However, it is possible to override it with optional argument COMPILED-FMT.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-colview.el.gz
(defun org-columns--collect-values (&optional compiled-fmt)
  "Collect values for columns on the current line.

Return a list of triplets (SPEC VALUE DISPLAYED) suitable for
`org-columns--display-here'.

This function assumes `org-columns-current-fmt-compiled' is
initialized is set in the current buffer.  However, it is
possible to override it with optional argument COMPILED-FMT."
  (let ((summaries (get-text-property (point) 'org-summaries)))
    (mapcar
     (lambda (spec)
       (pcase spec
	 (`(,p . ,_)
	  (let* ((v (or (cdr (assoc spec summaries))
			(org-entry-get (point) p 'selective t)
			(and compiled-fmt ;assume `org-agenda-columns'
			     ;; Effort property is not defined.  Try
			     ;; to use appointment duration.
			     org-agenda-columns-add-appointments-to-effort-sum
			     (string= p (upcase org-effort-property))
			     (get-text-property (point) 'duration)
			     (propertize (org-duration-from-minutes
					  (get-text-property (point) 'duration))
					 'face 'org-warning))
			"")))
	    ;; A non-nil COMPILED-FMT means we're calling from Org
	    ;; Agenda mode, where we do not want leading stars for
	    ;; ITEM.  Hence the optional argument for
	    ;; `org-columns--displayed-value'.
	    (list spec v (org-columns--displayed-value spec v compiled-fmt))))))
     (or compiled-fmt org-columns-current-fmt-compiled))))