Function: org-entities-help

org-entities-help is an interactive and byte-compiled function defined in org-entities.el.gz.

Signature

(org-entities-help)

Documentation

Create a Help buffer with all available entities.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-entities.el.gz
(defvar org-pretty-entities) ;; declare defcustom from org
(defun org-entities-help ()
  "Create a Help buffer with all available entities."
  (interactive)
  (with-output-to-temp-buffer "*Org Entity Help*"
    (princ "Org mode entities\n=================\n\n")
    (let ((ll (append '("* User-defined additions (variable org-entities-user)")
		      org-entities-user
		      org-entities))
	  (lastwasstring t)
	  (head (concat
		 "\n"
		 "   Symbol   Org entity        LaTeX code             HTML code\n"
		 "   -----------------------------------------------------------\n")))
      (dolist (e ll)
	(pcase e
	  (`(,name ,latex ,_ ,html ,_ ,_ ,utf8)
	   (when lastwasstring
	     (princ head)
	     (setq lastwasstring nil))
	   (princ (format "   %-8s \\%-16s %-22s %-13s\n"
			  utf8 name latex html)))
	  ((pred stringp)
	   (princ e)
	   (princ "\n")
	   (setq lastwasstring t))))))
  (with-current-buffer "*Org Entity Help*"
    (org-mode)
    (when org-pretty-entities
      (org-toggle-pretty-entities)))
  (select-window (get-buffer-window "*Org Entity Help*")))