Function: org-indent--compute-prefixes

org-indent--compute-prefixes is a byte-compiled function defined in org-indent.el.gz.

Signature

(org-indent--compute-prefixes)

Documentation

Compute prefix strings for regular text and headlines.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-indent.el.gz
(defun org-indent--compute-prefixes ()
  "Compute prefix strings for regular text and headlines."
  (setq org-indent--heading-line-prefixes
	(make-vector org-indent--deepest-level nil))
  (setq org-indent--inlinetask-line-prefixes
	(make-vector org-indent--deepest-level nil))
  (setq org-indent--text-line-prefixes
	(make-vector org-indent--deepest-level nil))
  (when (> org-indent-indentation-per-level 0)
    (dotimes (n org-indent--deepest-level)
      (let ((indentation (if (<= n 1) 0
			   (* (1- org-indent-indentation-per-level)
			      (1- n)))))
        ;; Headlines line prefixes.
        (let ((heading-prefix (make-string indentation ?*)))
	  (aset org-indent--heading-line-prefixes
                n
                (org-add-props heading-prefix nil 'face 'org-indent))
	  ;; Inline tasks line prefixes
	  (aset org-indent--inlinetask-line-prefixes
                n
                (cond ((<= n 1) "")
		      ((bound-and-true-p org-inlinetask-show-first-star)
		       (concat org-indent-inlinetask-first-star
			       (substring heading-prefix 1)))
		      (t (org-add-props heading-prefix nil 'face 'org-indent)))))
        ;; Text line prefixes.
        (aset org-indent--text-line-prefixes
	      n
	      (org-add-props
                  (concat (make-string (+ n indentation) ?\s)
                          (and (> n 0)
			       (char-to-string org-indent-boundary-char)))
                  nil 'face 'org-indent))))))