Function: org-latex-compile--postprocess

org-latex-compile--postprocess is a byte-compiled function defined in ox-latex.el.gz.

Signature

(org-latex-compile--postprocess OUTFILE LOG-BUF &optional SNIPPET)

Documentation

Process the results of creating OUTFILE via LaTeX compilation.

Warnings and errors are collected from LOG-BUF. When SNIPPET is nil and org-latex-remove-logfiles non-nil, log files (as specified by org-latex-logfiles-extensions) are deleted.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ox-latex.el.gz
(defun org-latex-compile--postprocess (outfile log-buf &optional snippet)
  "Process the results of creating OUTFILE via LaTeX compilation.
Warnings and errors are collected from LOG-BUF.
When SNIPPET is nil and `org-latex-remove-logfiles' non-nil,
log files (as specified by `org-latex-logfiles-extensions') are deleted."
  (unless snippet
    (when org-latex-remove-logfiles
      (mapc #'delete-file
            (directory-files
             (or (file-name-directory outfile) default-directory)
             t
             (concat (regexp-quote (file-name-base outfile))
                     "\\(?:\\.[0-9]+\\)?\\."
                     (regexp-opt org-latex-logfiles-extensions))
             t)))
    (let ((warnings (org-latex--collect-warnings log-buf)))
      (funcall
       (if warnings
           (apply-partially
            #'display-warning
            '(ox-latex))
         #'message)
       (concat "PDF file produced"
               (cond
                ((eq warnings 'error) " with errors.")
                (warnings (concat " with warnings: " warnings))
                (t ".")))))))