Function: org-link--normalize-filename

org-link--normalize-filename is a byte-compiled function defined in ol.el.gz.

Signature

(org-link--normalize-filename FILENAME &optional METHOD)

Documentation

Return FILENAME as required by METHOD.

METHOD defaults to the value of org-link-file-path-type.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ol.el.gz
(defun org-link--normalize-filename (filename &optional method)
  "Return FILENAME as required by METHOD.
METHOD defaults to the value of `org-link-file-path-type'."
  (setq method (or method org-link-file-path-type))
  (cond
   ((eq method 'absolute)
    (abbreviate-file-name (expand-file-name filename)))
   ((eq method 'noabbrev)
    (expand-file-name filename))
   ((eq method 'relative)
    (file-relative-name filename))
   ((functionp method)
    (funcall method filename))
   (t
    (save-match-data
      (if (string-match (concat "^" (regexp-quote
				     (expand-file-name
				      (file-name-as-directory
				       default-directory))))
			(expand-file-name filename))
	  ;; We are linking a file with relative path name.
	  (substring (expand-file-name filename)
		     (match-end 0))
	(abbreviate-file-name (expand-file-name filename)))))))