Function: org-lint-named-result

org-lint-named-result is a byte-compiled function defined in org-lint.el.gz.

Signature

(org-lint-named-result AST)

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-lint.el.gz
(defun org-lint-named-result (ast)
  (org-element-map ast org-element-all-elements
    (lambda (el)
      (when-let* ((result (org-element-property :results el))
                  (result-name (org-element-property :name el))
                  (origin-block
                   (if (org-string-nw-p (car result))
                       (condition-case _
                           (org-export-resolve-link (car result) `(:parse-tree ,ast))
                         (org-link-broken nil))
                     (org-export-get-previous-element el nil))))
        (when (and (org-element-type-p origin-block 'src-block)
                   (pcase-let ((`(,_ ,_ ,args . ,_)
                                (org-babel-get-src-block-info 'light origin-block)))
                     (not (member (alist-get :exports args) '("results" "both")))))
          (list (org-element-begin el)
                (format "Links to \"%s\" will not be valid during export unless the parent source block has :exports results or both" result-name)))))))