Function: org-odt-format-toc-headline

org-odt-format-toc-headline is a byte-compiled function defined in ox-odt.el.gz.

Signature

(org-odt-format-toc-headline TODO TODO-TYPE PRIORITY TEXT TAGS &key LEVEL SECTION-NUMBER HEADLINE-LABEL &allow-other-keys)

Source Code

;; Defined in /usr/src/emacs/lisp/org/ox-odt.el.gz
(cl-defun org-odt-format-toc-headline
    (todo _todo-type priority text tags
	  &key _level section-number headline-label &allow-other-keys)
  (format "<text:a xlink:type=\"simple\" xlink:href=\"#%s\">%s</text:a>"
	  headline-label
	  (concat
	   ;; Section number.
	   (and section-number (concat section-number ". "))
	   ;; Todo.
	   (when todo
	     (let ((style (if (member todo org-done-keywords)
			      "OrgDone" "OrgTodo")))
	       (format "<text:span text:style-name=\"%s\">%s</text:span> "
		       style todo)))
	   (when priority
	     (let* ((style (format "OrgPriority-%s" priority))
		    (priority (format "[#%c]" priority)))
	       (format "<text:span text:style-name=\"%s\">%s</text:span> "
		       style priority)))
	   ;; Title.
	   text
	   ;; Tags.
	   (when tags
	     (concat
	      (format " <text:span text:style-name=\"%s\">[%s]</text:span>"
		      "OrgTags"
		      (mapconcat
		       (lambda (tag)
			 (format
			  "<text:span text:style-name=\"%s\">%s</text:span>"
			  "OrgTag" tag)) tags " : ")))))))