Function: org-refile-new-child

org-refile-new-child is a byte-compiled function defined in org-refile.el.gz.

Signature

(org-refile-new-child PARENT-TARGET CHILD)

Documentation

Use refile target PARENT-TARGET to add new CHILD below it.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-refile.el.gz
(defun org-refile-new-child (parent-target child)
  "Use refile target PARENT-TARGET to add new CHILD below it."
  (unless parent-target
    (error "Cannot find parent for new node"))
  (let ((file (nth 1 parent-target))
	(pos (nth 3 parent-target))
	level)
    (with-current-buffer (find-file-noselect file 'nowarn)
      (org-with-wide-buffer
       (if pos
	   (goto-char pos)
	 (goto-char (point-max))
	 (unless (bolp) (newline)))
       (when (looking-at org-outline-regexp)
	 (setq level (funcall outline-level))
	 (org-end-of-subtree t t))
       (org-back-over-empty-lines)
       (insert "\n" (make-string
		     (if pos (org-get-valid-level level 1) 1) ?*)
	       " " child "\n")
       (forward-line -1)
       (list (concat (car parent-target) "/" child) file "" (point))))))