Function: pong-update-game

pong-update-game is a byte-compiled function defined in pong.el.gz.

Signature

(pong-update-game PONG-BUFFER)

Documentation

"Main" function for pong.

It is called every pong-cycle-delay seconds and updates ball and bats positions. It is responsible of collision detection and checks if a player scores.

Source Code

;; Defined in /usr/src/emacs/lisp/play/pong.el.gz
(defun pong-update-game (pong-buffer)
  "\"Main\" function for pong.
It is called every pong-cycle-delay seconds and
updates ball and bats positions.  It is responsible of collision
detection and checks if a player scores."
  (if (not (eq (current-buffer) pong-buffer))
      (pong-pause)

    (let ((old-x pong-x)
	  (old-y pong-y))
      ;; Erase the last ball position.
      (when (and (> old-y 0)
                 (< old-y (- pong-height 1)))
        ;; If the ball hit the bat in the column where bats are positioned,
        ;; and therefore changed its x direction, draw again the bat cell.
        (if (or (and (= old-x 2) (< 0 pong-xx))
                (and (= old-x (- pong-width 3)) (> 0 pong-xx)))
            (gamegrid-set-cell old-x old-y pong-bat)
          (gamegrid-set-cell old-x old-y pong-blank)))

      ;; Update the ball position.
      (setq pong-x (+ pong-x pong-xx))
      ;; If the ball would go out of bounds, put it against the border.
      (cond
       ((<= (+ pong-y pong-yy) 0)
        (setq pong-yy (- pong-yy))
        (setq pong-y 1))
       ((>= (+ pong-y pong-yy) (- pong-height 1))
        (setq pong-yy (- pong-yy))
        (setq pong-y (- pong-height 2)))
       (t
        (setq pong-y (+ pong-y pong-yy))
        ;; Check if the ball is against the border now,
        ;; and change the y direction if it is.
        (when (or (<= pong-y 1) (>= pong-y (- pong-height 2)))
          (setq pong-yy (- pong-yy)))))

      ;; Draw the ball in its new position.
      (if (and (> pong-y 0)
	       (< pong-y (- pong-height 1)))
	  (gamegrid-set-cell pong-x pong-y pong-ball))

      ;; Hit bat, score a goal, or nothing.
      (cond
       ((and (or (= pong-x 3) (= pong-x 2))
             (> 0 pong-xx) ; Collide with the bat if headed towards it.
             (>= pong-y pong-bat-player1)
             (< pong-y (+ pong-bat-player1 pong-bat-width)))
        (setq pong-yy (+ pong-yy
			 (cond
			  ((= pong-y pong-bat-player1) -1)
			  ((= pong-y (1+ pong-bat-player1)) 0)
			  (t 1))))
        (setq pong-xx (- pong-xx)))

       ((and (or (= pong-x (- pong-width 4)) (= pong-x (- pong-width 3)))
             (< 0 pong-xx) ; Collide with the bat if headed towards it.
             (>= pong-y pong-bat-player2)
             (< pong-y (+ pong-bat-player2 pong-bat-width)))
	(setq pong-yy (+ pong-yy
			 (cond
			  ((= pong-y pong-bat-player2) -1)
			  ((= pong-y (1+ pong-bat-player2)) 0)
			  (t 1))))
	(setq pong-xx (- pong-xx)))

       ((< pong-x 1)
	(setq pong-score-player2 (1+ pong-score-player2))
	(pong-init))

       ((>= pong-x (- pong-width 1))
	(setq pong-score-player1 (1+ pong-score-player1))
	(pong-init))))))