Function: preview-generate-preview

preview-generate-preview is a byte-compiled function defined in preview.el.

Signature

(preview-generate-preview FILE COMMAND)

Documentation

Generate a preview.

FILE the file (without default extension), COMMAND is the command to use.

It returns the started process.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
(defun preview-generate-preview (file command)
  "Generate a preview.
FILE the file (without default extension), COMMAND is the command
to use.

It returns the started process."
  (let* ((geometry (preview-get-geometry))
         (commandbuff (current-buffer))
         (pr-file (cons
                   #'TeX-active-master
                   (file-name-nondirectory file)))
         (master (TeX-master-file))
         (master-file (expand-file-name master))
         (dumped-cons (assoc master-file
                             preview-dumped-alist))
         process)
    (unless dumped-cons
      (push (setq dumped-cons (cons master-file
                                    (if (eq preview-auto-cache-preamble 'ask)
                                        (y-or-n-p "Cache preamble? ")
                                      preview-auto-cache-preamble)))
            preview-dumped-alist))
    (when (cdr dumped-cons)
      (let* (TeX-current-process-region-p)
        (setq process (preview-cache-preamble dumped-cons))
        (if process
            ;; FIXME: Use `add-function'.
            (setq TeX-sentinel-function
                  (let ((prev-fun TeX-sentinel-function))
                    (lambda (process string)
                      (funcall prev-fun process string)
                      (TeX-inline-preview-internal
                       command file
                       pr-file commandbuff
                       dumped-cons
                       master
                       geometry
                       (buffer-string))))))))
    (or process
        (TeX-inline-preview-internal command file
                                     pr-file commandbuff
                                     dumped-cons master
                                     geometry))))