Function: projectile-dashboard--collect-in-project

projectile-dashboard--collect-in-project is a byte-compiled function defined in projectile.el.

Signature

(projectile-dashboard--collect-in-project DIR ROOT)

Documentation

Collect the dashboard data for the project at ROOT, reached from DIR.

Must run in a buffer that has ROOT's directory-local variables applied - see projectile-dashboard--collect, which arranges that.

Source Code

;; Defined in ~/.emacs.d/elpa/projectile-20260820.1509/projectile.el
(defun projectile-dashboard--collect-in-project (dir root)
  "Collect the dashboard data for the project at ROOT, reached from DIR.
Must run in a buffer that has ROOT's directory-local variables applied -
see `projectile-dashboard--collect', which arranges that."
  (let* ((remote (file-remote-p root))
         (vcs (ignore-errors (projectile-project-vcs root)))
         (cached (gethash root projectile-projects-cache 'uncached))
         (project (projectile-dashboard--section-p 'project)))
    (append
     (list :dir dir
           :root root
           :remote remote
           :vcs vcs
           :frecency projectile-enable-frecency
           :name (when project (ignore-errors (projectile-project-name root)))
           :type (when project (ignore-errors (projectile-project-type)))
           :file-count (unless (eq cached 'uncached) (length cached))
           :buffer-count (length (ignore-errors (projectile-project-buffers root)))
           :links (when project
                    (ignore-errors
                      (projectile-dashboard--links
                       root (ignore-errors (projectile-project-type)))))
           :ignores (when project (projectile-dashboard--ignore-summary root))
           :recent-files (when (projectile-dashboard--section-p 'recent)
                           (projectile-dashboard--recent-files root))
           :tasks (when (projectile-dashboard--section-p 'tasks)
                    (ignore-errors (projectile-project-tasks nil root)))
           :commands (when (projectile-dashboard--section-p 'commands)
                       (ignore-errors (projectile-dashboard--commands root))))
     (when (projectile-dashboard--section-p 'vcs)
       (projectile-dashboard--vcs-info root vcs remote)))))