Function: projectile-doctor--file-info

projectile-doctor--file-info is a byte-compiled function defined in projectile.el.

Signature

(projectile-doctor--file-info ROOT REMOTE)

Documentation

Return a plist describing ROOT's file list and how it was obtained.

The cached list is used when there is one. Otherwise the project is indexed with caching bound off, so the doctor doesn't warm a cache the user didn't ask it to warm, and the timing of that run is reported. Indexing is skipped altogether when the project is REMOTE.

Source Code

;; Defined in ~/.emacs.d/elpa/projectile-20260820.1509/projectile.el
(defun projectile-doctor--file-info (root remote)
  "Return a plist describing ROOT's file list and how it was obtained.
The cached list is used when there is one.  Otherwise the project is
indexed with caching bound off, so the doctor doesn't warm a cache the
user didn't ask it to warm, and the timing of that run is reported.
Indexing is skipped altogether when the project is REMOTE."
  (let ((cached (gethash root projectile-projects-cache)))
    (cond
     (cached (list :file-count (length cached) :files-source 'cache))
     (remote (list :files-source 'skipped))
     (t (let* ((start (float-time))
               (files (condition-case err
                          ;; Index without touching the cache: no entry is
                          ;; stored, no stale entry is evicted, no file
                          ;; watch is armed.
                          (let ((projectile-enable-caching nil)
                                (projectile-files-cache-expire nil))
                            (projectile-project-files root))
                        (error (cons 'error (error-message-string err))))))
          (if (eq (car-safe files) 'error)
              (list :files-source 'error :files-error (cdr files))
            (list :file-count (length files)
                  :index-time (- (float-time) start)
                  :files-source 'fresh)))))))