Function: ps-do-despool

ps-do-despool is a byte-compiled function defined in ps-print.el.gz.

Signature

(ps-do-despool FILENAME)

Source Code

;; Defined in /usr/src/emacs/lisp/ps-print.el.gz
;; Permit dynamic evaluation at print time of `ps-lpr-switches'.
(defun ps-do-despool (filename)
  (if (or (not (boundp 'ps-spool-buffer))
	  (not (symbol-value 'ps-spool-buffer)))
      (message "No spooled PostScript to print")
    (if filename
	(save-excursion
	  (and ps-razzle-dazzle (message "Saving..."))
	  (set-buffer ps-spool-buffer)
	  (setq filename (expand-file-name filename))
	  (let ((coding-system-for-write 'raw-text-unix))
	    (write-region (point-min) (point-max) filename))
	  (and ps-razzle-dazzle (message "Wrote %s" filename)))
      ;; Else, spool to the printer
      (with-current-buffer ps-spool-buffer
	(let* ((coding-system-for-write 'raw-text-unix)
	       (printer-name (or ps-printer-name printer-name))
               (lpr-printer-switch ps-printer-name-option)
               (print-region-function ps-print-region-function)
               (lpr-command ps-lpr-command))
          (lpr-print-region (point-min) (point-max) ps-lpr-switches nil))))
    (kill-buffer ps-spool-buffer)))