Function: rcirc-markup-attributes

rcirc-markup-attributes is a byte-compiled function defined in rcirc.el.gz.

Signature

(rcirc-markup-attributes SENDER RESPONSE)

Documentation

Highlight IRC markup, indicated by ASCII control codes.

Source Code

;; Defined in /usr/src/emacs/lisp/net/rcirc.el.gz
(defun rcirc-markup-attributes (_sender _response)
  "Highlight IRC markup, indicated by ASCII control codes."
  (while (re-search-forward
          (rx (group (or #x02 #x1d #x1f #x1e #x11))
              (*? nonl)
              (group (or (backref 1) (+ #x0f) eol)))
          nil t)
    (rcirc-add-face (match-beginning 0) (match-end 0)
                    (cl-case (char-after (match-beginning 0))
                      (#x02 'bold)
                      (#x1d 'italic)
                      (#x1f 'underline)
                      (#x1e '(:strike-through t))
                      (#x11 'rcirc-monospace-text)))
    (goto-char (match-beginning 0))
    (forward-char)
    (unless (eq (char-before (match-end 2)) ?\C-o)
      (delete-region (match-beginning 2) (match-end 2)))
    (delete-region (match-beginning 1) (match-end 1))))