Function: reb-fontify-string-re

reb-fontify-string-re is a byte-compiled function defined in re-builder.el.gz.

Signature

(reb-fontify-string-re BOUND)

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/re-builder.el.gz
(defun reb-fontify-string-re (bound)
  (catch 'found
    ;; The following loop is needed to continue searching after matches
    ;; that do not occur in strings.  The associated regexp matches one
    ;; of `\\\\' `\\(' `\\(?:' `\\|' `\\)'.  `\\\\' has been included to
    ;; avoid highlighting, for example, `\\(' in `\\\\('.
    (when (memq reb-re-syntax '(read string))
      (while (re-search-forward
              (if (eq reb-re-syntax 'read)
                  ;; Copied from font-lock.el
                  "\\(\\\\\\\\\\)\\(?:\\(\\\\\\\\\\)\\|\\((\\(?:\\?[0-9]*:\\)?\\|[|)]\\)\\)"
                "\\(\\\\\\)\\(?:\\(\\\\\\)\\|\\((\\(?:\\?[0-9]*:\\)?\\|[|)]\\)\\)")
                bound t)
        (unless (match-beginning 2)
          (let ((face (get-text-property (1- (point)) 'face)))
            (when (or (and (listp face)
                           (memq 'font-lock-string-face face))
                      (eq 'font-lock-string-face face))
              (throw 'found t))))))))