Function: reftex-index-menu

reftex-index-menu is an interactive and byte-compiled function defined in reftex-index.el.gz.

Signature

(reftex-index-menu ARG1)

Documentation

Menu for Index buffer

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/reftex-index.el.gz
(defvar reftex-index-mode-map
  (let ((map (make-sparse-keymap)))
    ;; Index map
    (define-key map [(mouse-2)] #'reftex-index-mouse-goto-line-and-hide)
    (define-key map [follow-link] 'mouse-face)

    (define-key map [remap next-line] #'reftex-index-next)
    (define-key map [remap previous-line] #'reftex-index-previous)

    (define-key map "n" #'reftex-index-next)
    (define-key map "p" #'reftex-index-previous)
    (define-key map "?" #'reftex-index-show-help)
    (define-key map " " #'reftex-index-view-entry)
    (define-key map "\C-m" #'reftex-index-goto-entry-and-hide)
    (define-key map "\C-i" #'reftex-index-goto-entry)
    (define-key map "\C-k" #'reftex-index-kill)
    (define-key map "r" #'reftex-index-rescan)
    (define-key map "R" #'reftex-index-Rescan)
    (define-key map "g" #'revert-buffer)
    (define-key map "q" #'reftex-index-quit)
    (define-key map "k" #'reftex-index-quit-and-kill)
    (define-key map "f" #'reftex-index-toggle-follow)
    (define-key map "s" #'reftex-index-switch-index-tag)
    (define-key map "e" #'reftex-index-edit)
    (define-key map "^" #'reftex-index-level-up)
    (define-key map "_" #'reftex-index-level-down)
    (define-key map "}" #'reftex-index-restrict-to-section)
    (define-key map "{" #'reftex-index-widen)
    (define-key map ">" #'reftex-index-restriction-forward)
    (define-key map "<" #'reftex-index-restriction-backward)
    (define-key map "(" #'reftex-index-toggle-range-beginning)
    (define-key map ")" #'reftex-index-toggle-range-end)
    (define-key map "|" #'reftex-index-edit-attribute)
    (define-key map "@" #'reftex-index-edit-visual)
    (define-key map "*" #'reftex-index-edit-key)
    (define-key map "\C-c=" #'reftex-index-goto-toc)
    (define-key map "c" #'reftex-index-toggle-context)

    ;; The capital letters and the exclamation mark
    (mapc (lambda (key)
            (define-key map (vector (list key))
              (lambda () (interactive)
                (reftex-index-goto-letter key))))
          (concat "!" reftex-index-section-letters))

    (easy-menu-define reftex-index-menu map
      "Menu for Index buffer"
      '("Index"
        ["Goto section A-Z"
         (message "To go to a section, just press any of: !%s"
                  reftex-index-section-letters)
         t]
        ["Show Entry" reftex-index-view-entry t]
        ["Go To Entry" reftex-index-goto-entry t]
        ["Exit & Go To Entry" reftex-index-goto-entry-and-hide t]
        ["Table of Contents" reftex-index-goto-toc t]
        ["Quit" reftex-index-quit t]
        "--"
        ("Update"
         ["Rebuilt *Index* Buffer" revert-buffer t]
         "--"
         ["Rescan One File" reftex-index-rescan reftex-enable-partial-scans]
         ["Rescan Entire Document" reftex-index-Rescan t])
        ("Restrict"
         ["Restrict to section" reftex-index-restrict-to-section t]
         ["Widen" reftex-index-widen reftex-index-restriction-indicator]
         ["Next Section" reftex-index-restriction-forward
          reftex-index-restriction-indicator]
         ["Previous Section" reftex-index-restriction-backward
          reftex-index-restriction-indicator])
        ("Edit"
         ["Edit Entry" reftex-index-edit t]
         ["Edit Key" reftex-index-edit-key t]
         ["Edit Attribute" reftex-index-edit-attribute t]
         ["Edit Visual" reftex-index-edit-visual t]
         "--"
         ["Add Parentkey" reftex-index-level-down t]
         ["Remove Parentkey " reftex-index-level-up t]
         "--"
         ["Make Start-of-Range" reftex-index-toggle-range-beginning t]
         ["Make End-of-Range" reftex-index-toggle-range-end t]
         "--"
         ["Kill Entry" reftex-index-kill nil]
         "--"
         ["Undo" reftex-index-undo nil])
        ("Options"
         ["Context" reftex-index-toggle-context :style toggle
          :selected reftex-index-include-context]
         "--"
         ["Follow Mode" reftex-index-toggle-follow :style toggle
          :selected reftex-index-follow-mode])
        "--"
        ["Help" reftex-index-show-help t]))

    map)
  "Keymap used for *Index* buffers.")