Function: report-emacs-bug-check-org

report-emacs-bug-check-org is a byte-compiled function defined in emacsbug.el.gz.

Signature

(report-emacs-bug-check-org)

Documentation

Warn the user if the bug report mentions org-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/emacsbug.el.gz
(defun report-emacs-bug-check-org ()
  "Warn the user if the bug report mentions org-mode."
  (unless report-emacs-bug-no-confirmation
    (let* ((org-regex "\\(^\\|\\s-\\)[Oo]rg\\(-mode\\)?\\(\\s-\\|$\\)")
           (count (lambda (r s)
                    (let ((c 0) (start 0))
                      (while (string-match r s start)
                        (setq c (1+ c))
                        (setq start (match-end 0)))
                      c)))
           (m (funcall count org-regex (buffer-string)))
           (m-orig (funcall count org-regex report-emacs-bug-orig-text)))
      (when (> m m-orig)
        (when (yes-or-no-p "Is this bug about org-mode?")
          (error (substitute-command-keys "\
Not sending, use \\[org-submit-bug-report] to report an Org-mode bug.")))))))