Function: semantic-format-tag-name-from-anything

semantic-format-tag-name-from-anything is a byte-compiled function defined in format.el.gz.

Signature

(semantic-format-tag-name-from-anything ANYTHING &optional PARENT COLOR COLORHINT)

Documentation

Convert just about anything into a name like string.

Argument ANYTHING is the thing to be converted. Optional argument PARENT is the parent type if TAG is a detail. Optional argument COLOR means highlight the prototype with font-lock colors. Optional COLORHINT is the type of color to use if ANYTHING is not a tag with a tag class. See semantic--format-colorize-text for a definition of FACE-CLASS for which this is used.

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/semantic/format.el.gz
(defun semantic-format-tag-name-from-anything (anything &optional
							parent color
							colorhint)
  "Convert just about anything into a name like string.
Argument ANYTHING is the thing to be converted.
Optional argument PARENT is the parent type if TAG is a detail.
Optional argument COLOR means highlight the prototype with font-lock colors.
Optional COLORHINT is the type of color to use if ANYTHING is not a tag
with a tag class.  See `semantic--format-colorize-text' for a definition
of FACE-CLASS for which this is used."
  (cond ((stringp anything)
	 (semantic--format-colorize-text anything colorhint))
	((semantic-tag-p anything)
	 (let ((ans (semantic-format-tag-name anything parent color)))
	   ;; If ANS is empty string or nil, then the name wasn't
	   ;; supplied.  The implication is as in C where there is a data
	   ;; type but no name for a prototype from an include file, or
	   ;; an argument just wasn't used in the body of the fcn.
	   (if (or (null ans) (string= ans ""))
	       (setq ans (semantic-format-tag-type anything color)))
	   ans))
	((and (listp anything)
	      (stringp (car anything)))
	 (semantic--format-colorize-text (car anything) colorhint))))