Function: semantic-java-prototype-function

semantic-java-prototype-function is a byte-compiled function defined in java.el.gz.

Signature

(semantic-java-prototype-function TAG &optional PARENT COLOR)

Documentation

Return a function (method) prototype for TAG.

Optional argument PARENT is a parent (containing) item. Optional argument COLOR indicates that color should be mixed in. See also semantic-format-tag-prototype.

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/semantic/java.el.gz
;; Prototype handler
;;
(defun semantic-java-prototype-function (tag &optional _parent color)
  "Return a function (method) prototype for TAG.
Optional argument PARENT is a parent (containing) item.
Optional argument COLOR indicates that color should be mixed in.
See also `semantic-format-tag-prototype'."
  (let ((name (semantic-tag-name tag))
        (type (semantic-java-type tag))
        (tmpl (semantic-tag-get-attribute tag :template-specifier))
        (args (semantic-tag-function-arguments tag))
        (argp "")
        arg argt)
    (while args
      (setq arg  (car args)
            args (cdr args))
      (if (semantic-tag-p arg)
          (setq argt (if color
                         (semantic--format-colorize-text
                          (semantic-java-type arg) 'type)
                       (semantic-java-type arg))
                argp (concat argp argt (if args "," "")))))
    (when color
      (when type
        (setq type (semantic--format-colorize-text type 'type)))
      (setq name (semantic--format-colorize-text name 'function)))
    (concat (or tmpl "") (if tmpl " " "")
            (or type "") (if type " " "")
            name "(" argp ")")))