Function: spam-ifile-register-with-ifile

spam-ifile-register-with-ifile is a byte-compiled function defined in spam.el.gz.

Signature

(spam-ifile-register-with-ifile ARTICLES CATEGORY &optional UNREGISTER)

Documentation

Register an article, given as a string, with a category.

Uses gnus-newsgroup-name if category is nil (for ham registration).

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/spam.el.gz
(defun spam-ifile-register-with-ifile (articles category &optional unregister)
  "Register an article, given as a string, with a category.
Uses `gnus-newsgroup-name' if category is nil (for ham registration)."
  (let ((category (or category gnus-newsgroup-name))
        (add-or-delete-option (if unregister "-d" "-i"))
        (db (spam-get-ifile-database-parameter))
        ) ;; parameters
    (with-temp-buffer
      (dolist (article articles)
        (let ((article-string (spam-get-article-as-string article)))
          (when (stringp article-string)
            (insert article-string))))
      (apply #'call-process-region
             (point-min) (point-max) spam-ifile-program
             nil nil nil
             add-or-delete-option category
             (if db `(,db "-h") '("-h"))))))