Function: tags-search

tags-search is an autoloaded, interactive and byte-compiled function defined in etags.el.gz.

Signature

(tags-search REGEXP &optional FILES)

Documentation

Search through all files listed in tags table for match for REGEXP.

Stops when a match is found. To continue searching for next match, use the command M-x fileloop-continue (fileloop-continue).

If FILES if non-nil should be a list or an iterator returning the files to search. The search will be restricted to these files.

Also see the documentation of the tags-file-name variable.

View in manual

Probably introduced at or before Emacs version 1.8.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/etags.el.gz
;;;###autoload
(defun tags-search (regexp &optional files)
  "Search through all files listed in tags table for match for REGEXP.
Stops when a match is found.
To continue searching for next match, use the command \\[fileloop-continue].

If FILES if non-nil should be a list or an iterator returning the
files to search.  The search will be restricted to these files.

Also see the documentation of the `tags-file-name' variable."
  (interactive "sTags search (regexp): ")
  (unless (and (equal regexp "")
               ;; FIXME: If some other fileloop operation took place,
               ;; rather than search for "", we should repeat the last search!
	       (eq fileloop--operate-function
                   tags--last-search-operate-function))
    (fileloop-initialize-search
     regexp
     (tags--compat-files (or files t))
     tags-case-fold-search)
    ;; Store it, so we can detect if some other fileloop operation took
    ;; place since the last search!
    (setq tags--last-search-operate-function fileloop--operate-function))
  (fileloop-continue))