Function: testcover-analyze-coverage-wrapped-application

testcover-analyze-coverage-wrapped-application is a byte-compiled function defined in testcover.el.gz.

Signature

(testcover-analyze-coverage-wrapped-application FUNC ARGS)

Documentation

Analyze the application of FUNC to ARGS for code coverage.

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/testcover.el.gz
(defun testcover-analyze-coverage-wrapped-application (func args)
  "Analyze the application of FUNC to ARGS for code coverage."
  (cond
   ((eq func 'quote) 'testcover-1value)
   ((or (memq func testcover-1value-functions)
        (memq func testcover-module-1value-functions))
    ;; The function should always return the same value.
    (testcover-analyze-coverage-progn args)
    'testcover-1value)
   ((or (memq func testcover-potentially-1value-functions)
        (memq func testcover-module-potentially-1value-functions))
    ;; The function might always return the same value.
    (testcover-analyze-coverage-progn args)
    'maybe)
   ((memq func testcover-progn-functions)
    ;; The function is 1-valued if the last argument is.
    (testcover-analyze-coverage-progn args))
   ((memq func testcover-prog1-functions)
    ;; The function is 1-valued if first argument is.
    (testcover-analyze-coverage-progn (cdr args))
    (testcover-analyze-coverage (car args)))
   ((memq func testcover-compose-functions)
    ;; The function is 1-valued if all arguments are, and potentially
    ;; 1-valued if all arguments are either definitely or potentially.
    (testcover-analyze-coverage-compose args #'testcover-analyze-coverage))
   (t (testcover-analyze-coverage-progn args)
      nil)))