Function: time-stamp-conv-warn

time-stamp-conv-warn is a byte-compiled function defined in time-stamp.el.gz.

Signature

(time-stamp-conv-warn OLD-FORMAT NEW-FORMAT &optional STANDARD-FORMAT)

Documentation

Display a warning about a soon-to-be-obsolete format.

Suggests replacing OLD-FORMAT with NEW-FORMAT (same effect, but stable) or (if provided) STANDARD-FORMAT (the effect the user may have expected if they didn't read the documentation). This is an internal function called by time-stamp.

Source Code

;; Defined in /usr/src/emacs/lisp/time-stamp.el.gz
(defun time-stamp-conv-warn (old-format new-format &optional standard-format)
  "Display a warning about a soon-to-be-obsolete format.
Suggests replacing OLD-FORMAT with NEW-FORMAT (same effect, but stable)
or (if provided) STANDARD-FORMAT (the effect the user may have expected
if they didn't read the documentation).
This is an internal function called by `time-stamp'."
  (cond
   (time-stamp-conversion-warn
    (with-current-buffer (get-buffer-create "*Time-stamp-compatibility*")
      (goto-char (point-max))
      (cond
       ((bobp)
        (insert
         (substitute-quotes
          (concat
           "The conversions recognized in `time-stamp-format' will change in a future\n"
           "release to be more compatible with the function `format-time-string'.\n"
           (cond
            (standard-format
             (concat
              "Conversions that are changing are ambiguous and are best replaced by\n"
              "stable conversions that make your intention clear.\n")))
           "\n"
           "The following obsolescent `time-stamp-format' conversion(s) were found:\n\n")))))
      (insert old-format " -- use " new-format)
      (if standard-format
          (insert " or " standard-format))
      (insert "\n")
      (help-make-xrefs))
    (display-buffer "*Time-stamp-compatibility*"))))