Function: toggle-case-fold-search

toggle-case-fold-search is an interactive and byte-compiled function defined in menu-bar.el.gz.

Signature

(toggle-case-fold-search &optional INTERACTIVELY)

Documentation

Toggle whether to ignore letter-case in search commands.

In an interactive call, record this option as a candidate for saving by "Save Options" in Custom buffers.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/menu-bar.el.gz
(defvar menu-bar-search-options-menu
  (let ((menu (make-sparse-keymap "Search Options")))

    (dolist (x '((char-fold-to-regexp "Fold Characters" "Character folding")
                 (isearch-symbol-regexp "Whole Symbols" "Whole symbol")
                 (word-search-regexp "Whole Words" "Whole word")))
      (define-key menu (vector (nth 0 x))
        `(menu-item ,(nth 1 x)
                    ,(lambda ()
                       (interactive)
                       (setq search-default-mode (nth 0 x))
                       (message "%s search enabled" (nth 2 x)))
                    :help ,(format "Enable %s search" (downcase (nth 2 x)))
                    :button (:radio . (eq search-default-mode #',(nth 0 x))))))

    (define-key menu [regexp-search]
      `(menu-item "Regular Expression"
                  ,(lambda ()
                     (interactive)
                     (setq search-default-mode t)
                     (message "Regular-expression search enabled"))
                  :help "Enable regular-expression search"
                  :button (:radio . (eq search-default-mode t))))

    (define-key menu [regular-search]
      `(menu-item "Literal Search"
                  ,(lambda ()
                     (interactive)
                     (when search-default-mode
                       (setq search-default-mode nil)
                       (when (symbolp search-default-mode)
                         (message "Literal search enabled"))))
                  :help "Disable special search modes"
                  :button (:radio . (not search-default-mode))))

    (define-key menu [custom-separator]
      menu-bar-separator)
    (define-key menu [case-fold-search]
      (menu-bar-make-toggle-command
       toggle-case-fold-search case-fold-search
       "Ignore Case"
       "Case-Insensitive Search %s"
       "Ignore letter-case in search commands"))

    menu))