Function: tramp-debug-link-messages

tramp-debug-link-messages is a byte-compiled function defined in tramp-message.el.gz.

Signature

(tramp-debug-link-messages POS1 POS2)

Documentation

Set links for two messages in current buffer.

The link buttons are in the verbositiy level substrings.

Source Code

;; Defined in /usr/src/emacs/lisp/net/tramp-message.el.gz
(defun tramp-debug-link-messages (pos1 pos2)
  "Set links for two messages in current buffer.
The link buttons are in the verbositiy level substrings."
  (declare (tramp-suppress-trace t))
  (save-excursion
    (let (beg1 end1 beg2 end2)
      (goto-char pos1)
      ;; Find positions.
      (while (not (search-forward-regexp
		   tramp-debug-outline-regexp (line-end-position) t))
	(forward-line))
      (setq beg1 (1- (match-beginning 3)) end1 (1+ (match-end 3)))
      (goto-char pos2)
      (while (not (search-forward-regexp
		   tramp-debug-outline-regexp (line-end-position) t))
	(forward-line))
      (setq beg2 (1- (match-beginning 3)) end2 (1+ (match-end 3)))
      ;; Create text buttons.
      (make-text-button
       beg1 end1 :type 'tramp-debug-button-type
       'position (set-marker (make-marker) beg2)
       'help-echo "mouse-2, RET: goto exit message")
      (make-text-button
       beg2 end2 :type 'tramp-debug-button-type
       'position (set-marker (make-marker) beg1)
       'help-echo "mouse-2, RET: goto entry message"))))