Function: tramp-use-absolute-autoload-file-names

tramp-use-absolute-autoload-file-names is a byte-compiled function defined in tramp.el.gz.

Signature

(tramp-use-absolute-autoload-file-names)

Documentation

Change Tramp autoload objects to use absolute file names.

This avoids problems during autoload, when load-path contains remote file names.

Source Code

;; Defined in /usr/src/emacs/lisp/net/tramp.el.gz
;;;###autoload (tramp-register-autoload-file-name-handlers)

(defun tramp-use-absolute-autoload-file-names ()
  "Change Tramp autoload objects to use absolute file names.
This avoids problems during autoload, when `load-path' contains
remote file names."
  ;; We expect all other Tramp files in the same directory as tramp.el.
  (let* ((dir (expand-file-name (file-name-directory (locate-library "tramp"))))
	 (files (seq-uniq
		 (mapcar
		  #'file-name-sans-extension
		  (directory-files
		   dir nil (rx bos "tramp" (+ nonl) ".el" (? "c") eos)))))
	 (files-regexp (rx bol (regexp (regexp-opt files)) eol)))
    (mapatoms
     (lambda (atom)
       (when (and (functionp atom)
		  (autoloadp (symbol-function atom))
		  (string-match-p files-regexp (cadr (symbol-function atom))))
	 (ignore-errors
	   (setf (cadr (symbol-function atom))
		 (expand-file-name (cadr (symbol-function atom)) dir))))))))