Function: url-setup-privacy-info

url-setup-privacy-info is an autoloaded, interactive and byte-compiled function defined in url-privacy.el.gz.

Signature

(url-setup-privacy-info)

Documentation

Setup variables that expose info about you and your system.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/url/url-privacy.el.gz
;;;###autoload
(defun url-setup-privacy-info ()
  "Setup variables that expose info about you and your system."
  (interactive)
  (setq url-system-type
	(cond
	 ((or (eq url-privacy-level 'paranoid)
	      (and (listp url-privacy-level)
		   (memq 'os url-privacy-level)))
	  nil)
	 ;; First, we handle the inseparable OS/Windowing system
	 ;; combinations
	 ((memq system-type '(windows-nt cygwin))
          (concat "MS-Windows; "
                  (if (string-match-p "\\`x86_64" system-configuration)
                      "64bit"
                    "32bit")
                  "; "
                  (cond ((eq window-system 'w32) "w32")
                        ((eq window-system 'x) "X11")
                        (t "TTY"))))
	 ((eq system-type 'ms-dos) "MS-DOS; 32bit")
	 (t
	  (pcase (or window-system 'tty)
	    ('x "X11")
	    ('ns "OpenStep")
            ('pgtk "PureGTK")
	    ('tty "TTY")
	    (_ nil)))))

  (setq url-os-type
	(cond
	 ((or (eq url-privacy-level 'paranoid)
	      (and (listp url-privacy-level)
		   (memq 'os url-privacy-level)))
	  nil)
	 ((boundp 'system-configuration) system-configuration)
	 ((boundp 'system-type) (symbol-name system-type))
	 (t nil))))