Function: vc-annotate-lines

vc-annotate-lines is a byte-compiled function defined in vc-annotate.el.gz.

Signature

(vc-annotate-lines LIMIT)

Source Code

;; Defined in /usr/src/emacs/lisp/vc/vc-annotate.el.gz
(defun vc-annotate-lines (limit)
  (while (< (point) limit)
    (let ((difference (vc-annotate-difference vc-annotate-offset))
          (start (point))
          (end (progn (forward-line 1) (point))))
      (when difference
        (let* ((color (or (vc-annotate-compcar difference vc-annotate-color-map)
                          (cons nil vc-annotate-very-old-color)))
               ;; substring from index 1 to remove any leading `#' in the name
               (face (intern (concat "vc-annotate-face-"
                                     (if (string-equal
                                          (substring (cdr color) 0 1) "#")
                                         (substring (cdr color) 1)
                                       (cdr color)))))
               ;; Make the face if not done.
               (face (if (facep face)
                         face
                       (make-face face)
                       (set-face-extend face t)
                       (cond
                        (vc-annotate-background-mode
                         (set-face-background face (cdr color)))
                        (t
                         (set-face-foreground face (cdr color))
                         (when vc-annotate-background
			   (set-face-background face vc-annotate-background))))
                       face)))
          (put-text-property start end 'face face)))))
  ;; Pretend to font-lock there were no matches.
  nil)