Function: vc-edit-next-command

vc-edit-next-command is an autoloaded, interactive and byte-compiled function defined in vc.el.gz.

Signature

(vc-edit-next-command)

Documentation

Request editing the next VC shell command before execution.

This is a prefix command. It affects only a VC command executed immediately after this one.

View in manual

Probably introduced at or before Emacs version 29.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/vc/vc.el.gz
;;;###autoload
(defun vc-edit-next-command ()
  "Request editing the next VC shell command before execution.
This is a prefix command.  It affects only a VC command executed
immediately after this one."
  (interactive)
  (letrec ((minibuffer-depth (minibuffer-depth))
           (command this-command)
           (keys (key-description (this-command-keys)))
           (old vc-filter-command-function)
           (echofun (lambda () keys))
           (postfun
            (lambda ()
              (unless (or (eq this-command command)
                          (> (minibuffer-depth) minibuffer-depth))
                (remove-hook 'post-command-hook postfun)
                (remove-hook 'prefix-command-echo-keystrokes-functions
                             echofun)
                (setq vc-filter-command-function old)))))
    (add-hook 'post-command-hook postfun)
    (add-hook 'prefix-command-echo-keystrokes-functions echofun)
    (setq vc-filter-command-function
          (lambda (&rest args)
            (apply #'vc-user-edit-command (apply old args))))))