Function: vc-hg-project-list-files

vc-hg-project-list-files is a byte-compiled function defined in project.el.gz.

Signature

(vc-hg-project-list-files DIR EXTRA-IGNORES)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/project.el.gz
(defun vc-hg-project-list-files (dir extra-ignores)
  (let* ((default-directory (expand-file-name (file-name-as-directory dir)))
         (include-untracked (project--value-in-dir
                             'project-vc-include-untracked
                             dir))
         (args (list (concat "-mcard" (and include-untracked "u"))
                     "--no-status"
                     "-0"))
         files)
    (when extra-ignores
      (setq args (nconc args
                        (mapcan
                         (lambda (i)
                           (list "--exclude" i))
                         extra-ignores))))
    (with-temp-buffer
      (apply #'vc-hg-command t 0 "." "status" args)
      (setq files (split-string (buffer-string) "\0" t))
      (unless project-files-relative-names
        (setq files (mapcar
                     (lambda (s) (concat default-directory s))
                     files)))
      files)))