Function: verilog--pretty-expr-find-end

verilog--pretty-expr-find-end is a byte-compiled function defined in verilog-mode.el.gz.

Signature

(verilog--pretty-expr-find-end &optional DISCARD-RE REG-END)

Documentation

Find end position for current alignment of expressions.

Use optional arg DISCARD-RE when aligning expressions outside of an argument list and REG-END to set a limit on the alignment when the region is active.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/verilog-mode.el.gz
(defun verilog--pretty-expr-find-end (&optional discard-re reg-end)
  "Find end position for current alignment of expressions.
Use optional arg DISCARD-RE when aligning expressions outside of an
argument list and REG-END to set a limit on the alignment when the
region is active."
  (if (verilog-in-parenthesis-p)
      ;; Limit end in argument list
      (progn
        (verilog-backward-up-list -1)
        (forward-char -1)
        (verilog-backward-syntactic-ws)
        (if (region-active-p)
            (min reg-end (point))
          (point)))
    ;; Limit end in non-argument list
    (save-excursion ; EOL of the last line of the assignment block
      (end-of-line)
      (let ((pt (point))) ; Might be on last line
        (verilog-forward-syntactic-ws)
        (beginning-of-line)
        (while (and (verilog--pretty-expr-assignment-found discard-re)
                    (progn
                      (end-of-line)
                      (not (eq pt (point)))))
          (setq pt (point))
          (verilog-forward-syntactic-ws)
          (beginning-of-line))
        (if (region-active-p)
            (min reg-end pt)
          pt)))))