Function: vertico-unobtrusive-mode

vertico-unobtrusive-mode is an autoloaded, interactive and byte-compiled function defined in vertico-unobtrusive.el.

Signature

(vertico-unobtrusive-mode &optional ARG)

Documentation

Unobtrusive display for Vertico.

This is a global minor mode. If called interactively, toggle the Vertico-Unobtrusive mode mode. If the prefix argument is positive, enable the mode, and if it is zero or negative, disable the mode.

If called from Lisp, toggle the mode if ARG is toggle. Enable the mode if ARG is nil, omitted, or is a positive number. Disable the mode if ARG is a negative number.

To check whether the minor mode is enabled in the current buffer, evaluate (default-value \=vertico-unobtrusive-mode)'.

The mode's hook is called both when the mode is enabled and when it is disabled.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/vertico-20260811.1003/vertico-unobtrusive.el
;;;###autoload
(define-minor-mode vertico-unobtrusive-mode
  "Unobtrusive display for Vertico."
  :global t :group 'vertico
  (cond
   ((and vertico-unobtrusive-mode (not vertico-unobtrusive--restore))
    (push '(vertico-current . default) (default-value 'face-remapping-alist))
    (setq vertico-unobtrusive--restore (cons vertico-count vertico-count-format)
          vertico-count 1
          vertico-count-format nil
          vertico-flat-format `(:separator nil :ellipsis nil ,@vertico-flat-format)))
   ((and (not vertico-unobtrusive-mode) vertico-unobtrusive--restore)
    (cl-callf2 delete '(vertico-current . default)
               (default-value 'face-remapping-alist))
    (setq vertico-count (car vertico-unobtrusive--restore)
          vertico-count-format (cdr vertico-unobtrusive--restore)
          vertico-flat-format (nthcdr 4 vertico-flat-format)
          vertico-unobtrusive--restore nil)))
  (vertico-flat-mode (if vertico-unobtrusive-mode 1 -1)))