Function: which-key-C-h-dispatch

which-key-C-h-dispatch is an autoloaded, interactive and byte-compiled function defined in which-key.el.gz.

Signature

(which-key-C-h-dispatch)

Documentation

Dispatch \C-h commands by looking up key in which-key-C-h-map.

This command is always accessible (from any prefix) if which-key-use-C-h-commands is non nil.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/which-key.el.gz
;;;###autoload
(defun which-key-C-h-dispatch ()
  "Dispatch \\`C-h' commands by looking up key in `which-key-C-h-map'.
This command is always accessible (from any prefix) if
`which-key-use-C-h-commands' is non nil."
  (interactive)
  (cond ((and (not (which-key--popup-showing-p))
              which-key-show-early-on-C-h)
         (let ((current-prefix
                (butlast
                 (listify-key-sequence
                  (funcall which-key-this-command-keys-function)))))
           (which-key-reload-key-sequence current-prefix)
           (if which-key-idle-secondary-delay
               (which-key--start-timer which-key-idle-secondary-delay t)
             (which-key--start-timer 0.05 t))))
        ((not (which-key--popup-showing-p))
         (which-key-show-standard-help))
        (t
         (if (not (which-key--popup-showing-p))
             (which-key-show-standard-help)
           (let* ((prefix-keys (which-key--current-key-string))
                  (full-prefix (which-key--full-prefix prefix-keys current-prefix-arg t))
                  (prompt (concat (when (string-equal prefix-keys "")
                                    (which-key--propertize
                                     (concat " "
                                             (which-key--pages-prefix-title
                                              which-key--pages-obj))
                                     'face 'which-key-note-face))
                                  full-prefix
                                  (which-key--propertize
                                   (substitute-command-keys
                                    which-key-C-h-map-prompt)
                                   'face 'which-key-note-face)))
                  (key (let ((key (read-key prompt)))
                         (if (numberp key)
                             (string key)
                           (vector key))))
                  (cmd (lookup-key which-key-C-h-map key))
                  (which-key-inhibit t))
             (if cmd (funcall cmd key) (which-key-turn-page 0)))))))