Variable: bibtex-mode-abbrev-table

bibtex-mode-abbrev-table is a variable defined in bibtex.el.gz.

Value

#<obarray n=1>

Documentation

Abbrev table for bibtex-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/bibtex.el.gz
;; Interactive Functions:

;;;###autoload
(define-derived-mode bibtex-mode nil "BibTeX"
  "Major mode for editing BibTeX files.

General information on working with BibTeX mode:

Use commands such as \\<bibtex-mode-map>\\[bibtex-Book] to get a template for a specific entry.
Then fill in all desired fields using \\[bibtex-next-field] to jump from field
to field.  After having filled in all desired fields in the entry, clean the
new entry with the command \\[bibtex-clean-entry].

Some features of BibTeX mode are available only by setting the variable
`bibtex-maintain-sorted-entries' to non-nil.  However, then BibTeX mode
works only with buffers containing valid (syntactically correct) and sorted
entries.  This is usually the case, if you have created a buffer completely
with BibTeX mode and finished every new entry with \\[bibtex-clean-entry].

For third party BibTeX files, call the command \\[bibtex-convert-alien]
to fully take advantage of all features of BibTeX mode.


Special information:

A command such as \\[bibtex-Book] outlines the fields for a BibTeX book entry.

The names of optional fields start with the string OPT, and are thus ignored
by BibTeX.  The names of alternative fields from which only one is required
start with the string ALT.  The OPT or ALT string may be removed from
the name of a field with \\[bibtex-remove-OPT-or-ALT].
\\[bibtex-make-field] inserts a new field after the current one.
\\[bibtex-kill-field] kills the current field entirely.
\\[bibtex-yank] yanks the last recently killed field after the current field.
\\[bibtex-remove-delimiters] removes the double-quotes or braces around the text of the current field.
\\[bibtex-empty-field] replaces the text of the current field with the default \"\" or {}.
\\[bibtex-find-text] moves point to the end of the current field.
\\[completion-at-point] completes word fragment before point according to context.

The command \\[bibtex-clean-entry] cleans the current entry, i.e. it removes OPT/ALT
from the names of all non-empty optional or alternative fields, checks that
no required fields are empty, and does some formatting dependent on the value
of `bibtex-entry-format'.  Furthermore, it can automatically generate a key
for the BibTeX entry, see `bibtex-generate-autokey'.
Note: some functions in BibTeX mode depend on entries being in a special
format (all fields beginning on separate lines), so it is usually a bad
idea to remove `realign' from `bibtex-entry-format'.

BibTeX mode supports Imenu and hideshow minor mode (`hs-minor-mode').

----------------------------------------------------------
Entry to BibTeX mode calls the value of `bibtex-mode-hook'
if that value is non-nil.

\\{bibtex-mode-map}"
  (add-hook 'completion-at-point-functions
            #'bibtex-completion-at-point-function nil 'local)
  (make-local-variable 'bibtex-buffer-last-parsed-tick)
  ;; Install stealthy parse function if not already installed
  (unless bibtex-parse-idle-timer
    (setq bibtex-parse-idle-timer (run-with-idle-timer
                                   bibtex-parse-keys-timeout t
                                   #'bibtex-parse-buffers-stealthily)))
  (setq-local paragraph-start "[ \f\n\t]*$")
  (setq-local comment-column 0)
  (setq-local defun-prompt-regexp "^[ \t]*@[[:alnum:]]+[ \t]*")
  (setq-local outline-regexp "[ \t]*@")
  (setq-local hs-block-start-regexp "@\\S(*\\(\\s(\\)"
              hs-block-start-mdata-select 1)
  (setq-local fill-paragraph-function #'bibtex-fill-field)
  (setq-local font-lock-defaults
              '(bibtex-font-lock-keywords
                nil t ((?$ . ".")
                       ;; Mathematical expressions should be fontified
                       ;; as strings.  Yet `$' may also appear in certain
                       ;; fields like `URL' when it does not delimit
                       ;; a math expression (bug#50202).
                       (?\" . ".")
                       ;; Quotes are field delimiters and quote-delimited
                       ;; entries should be fontified in the same way as
                       ;; brace-delimited ones
                       )
                nil
                (font-lock-extra-managed-props . (category))
                (font-lock-mark-block-function
                 . (lambda ()
                     (set-mark (bibtex-end-of-entry))
                     (bibtex-beginning-of-entry)))))
  (setq-local syntax-propertize-function
              (syntax-propertize-via-font-lock
               bibtex-font-lock-syntactic-keywords))
  (let ((fun (lambda ()
               ;; `bibtex-dialect' and the other bibtex variables listed here
               ;; may appear as file-local variables.  So any variables whose
               ;; values are derived from these bibtex variables must honor
               ;; the file-local values.
               (bibtex-set-dialect)
               (setq-local comment-start bibtex-comment-start)
               (setq-local comment-start-skip
                           (concat (regexp-quote bibtex-comment-start) "\\>[ \t]*"))
               (setq-local fill-prefix
                           (make-string (+ bibtex-entry-offset
                                           bibtex-contline-indentation)
                                        ?\s)))))
    (if (and buffer-file-name enable-local-variables)
        (add-hook 'hack-local-variables-hook fun nil t)
      (funcall fun)))
  ;; We may be using the mode programmatically to extract data, and we
  ;; then need this to be set up first so that sexp-based movement
  ;; commands don't bug out.
  (font-lock-set-defaults))