Variable: cfengine3-mode-map

cfengine3-mode-map is a variable defined in cfengine.el.gz.

Value

Documentation

Keymap for cfengine3-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/cfengine.el.gz
;;;###autoload
(define-derived-mode cfengine3-mode prog-mode "CFE3"
  "Major mode for editing CFEngine3 input.
There are no special keybindings by default.

Action blocks are treated as defuns, i.e. \\[beginning-of-defun] moves
to the action header."
  (cfengine-common-settings)
  (cfengine-common-syntax cfengine3-mode-syntax-table)

  (setq-local indent-line-function #'cfengine3-indent-line)

  (setq font-lock-defaults
        '(cfengine3-font-lock-keywords
          nil nil nil beginning-of-defun))
  (setq-local prettify-symbols-alist cfengine3--prettify-symbols-alist)

  ;; `compile-command' is almost never a `make' call with CFEngine so
  ;; we override it
  (when cfengine-cf-promises
    (setq-local compile-command
                (concat cfengine-cf-promises
                        " -f "
                        (when buffer-file-name
                          (shell-quote-argument buffer-file-name)))))

  (add-hook 'eldoc-documentation-functions
            #'cfengine3-documentation-function nil t)

  (add-hook 'completion-at-point-functions
            #'cfengine3-completion-function nil t)

  ;; Use defuns as the essential syntax block.
  (setq-local beginning-of-defun-function #'cfengine3-beginning-of-defun)
  (setq-local end-of-defun-function #'cfengine3-end-of-defun)

  (setq-local imenu-create-index-function #'cfengine3-create-imenu-index)
  (setq-local add-log-current-defun-function #'cfengine3-current-defun))