Variable: editorconfig-conf-mode-map

editorconfig-conf-mode-map is a variable defined in editorconfig-conf-mode.el.gz.

Value

Documentation

Keymap for editorconfig-conf-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/editorconfig-conf-mode.el.gz
;;;###autoload
(define-derived-mode editorconfig-conf-mode conf-unix-mode "Conf[EditorConfig]"
  "Major mode for editing .editorconfig files."
  (set-variable 'indent-line-function 'indent-relative)
  (let ((key-property-list
         '("charset"
           "end_of_line"
           "file_type_emacs"
           "file_type_ext"
           "indent_size"
           "indent_style"
           "insert_final_newline"
           "max_line_length"
           "root"
           "tab_width"
           "trim_trailing_whitespace"))
        (key-value-list
         '("unset"
           "true"
           "false"
           "lf"
           "cr"
           "crlf"
           "space"
           "tab"
           "latin1"
           "utf-8"
           "utf-8-bom"
           "utf-16be"
           "utf-16le"))
        (font-lock-value
         '(("^[ \t]*\\[\\(.+?\\)\\]" 1 font-lock-type-face)
           ("^[ \t]*\\(.+?\\)[ \t]*[=:]" 1 font-lock-variable-name-face))))

    ;; Highlight all key values
    (dolist (key-value key-value-list)
      (push `(,(format "[=:][ \t]*\\(%s\\)\\([ \t]\\|$\\)" key-value)
              1 font-lock-constant-face)
            font-lock-value))
    ;; Highlight all key properties
    (dolist (key-property key-property-list)
      (push `(,(format "^[ \t]*\\(%s\\)[ \t]*[=:]" key-property)
              1 font-lock-builtin-face)
            font-lock-value))

    (conf-mode-initialize "#" font-lock-value)))